问题 在perl中随机化矩阵，保持行和列总数相同

你当前算法的问题在于你试图将你的方式摆脱死胡同 - 特别是当你的时候 @letters 和 @numbers 数组（在最初的shuffle之后） @numbers）不止一次产生相同的细胞。当矩阵很小时，这种方法很有效，因为它不需要太多的尝试来找到可行的重新洗牌。然而，当名单很大时，这是一个杀手。即使您可以更有效地寻找替代方案 - 例如，尝试排列而不是随机改组 - 这种方法可能注定失败。

您可以通过对现有矩阵进行少量修改来解决问题，而不是改变整个列表。

例如，让我们从您的示例矩阵开始（称之为M1）。随机选择一个单元格进行更改（例如，A1）。此时矩阵处于非法状态。我们的目标是将其修改为最少的编辑次数 - 特别是3次编辑。您通过在矩阵周围“行走”来实现这3个额外的编辑，每行修复一行或列会产生另一个需要解决的问题，直到您走完整圆（错误...全矩形）。

例如，在将A1从0更改为1之后，有3种方法可以进行下一次修复：A3，B1和C1。让我们决定第一次编辑应该修复行。所以我们选择A3。在第二次编辑时，我们将修复列，因此我们有选择：B3或C3（比如C3）。最终修复只提供一个选项（C1），因为我们需要返回原始编辑的列。最终结果是一个新的有效矩阵。

    Orig         Change A1     Change A3     Change C3     Change C1
    M1                                                     M2

    1 2 3        1 2 3         1 2 3         1 2 3         1 2 3
    -----        -----         -----         -----         -----
A | 0 0 1        1 0 1         1 0 0         1 0 0         1 0 0
B | 1 1 0        1 1 0         1 1 0         1 1 0         1 1 0
C | 1 0 0        1 0 0         1 0 0         1 0 1         0 0 1

如果编辑路径导致死胡同，则回溯。如果所有修复路径都失败，则可以拒绝初始编辑。

这种方法可以快速生成新的有效矩阵。它不一定会产生随机结果：M1和M2仍然会彼此高度相关，随着矩阵大小的增加，这一点将变得更加明显。

你如何增加随机性？你提到大多数细胞（99％或更多）都是零。一个想法是这样进行：对于矩阵中的每个1，将其值设置为0，然后使用上面概述的4编辑方法修复矩阵。实际上，您将把所有这些移动到新的随机位置。

这是一个例子。这里可能还有进一步的速度优化，但这种方法在我的Windows机器上30秒左右产生了10个新的600x600矩阵，密度为0.5％。不知道那是否足够快。

use strict;
use warnings;

# Args: N rows, N columns, density, N iterations.
main(@ARGV);

sub main {
    my $n_iter = pop;
    my $matrix = init_matrix(@_);
    print_matrix($matrix);
    for my $n (1 .. $n_iter){
        warn $n, "\n"; # Show progress.
        edit_matrix($matrix);
        print_matrix($matrix);
    }
}

sub init_matrix {
    # Generate initial matrix, given N of rows, N of cols, and density.
    my ($rows, $cols, $density) = @_;
    my @matrix;
    for my $r (1 .. $rows){
        push @matrix, [ map { rand() < $density ? 1 : 0  } 1 .. $cols ];
    }
    return \@matrix;
}

sub print_matrix {
    # Dump out a matrix for checking.
    my $matrix = shift;
    print "\n";
    for my $row (@$matrix){
        my @vals = map { $_ ? 1 : ''} @$row;
        print join("\t", @vals), "\n";
    }
}

sub edit_matrix {
    # Takes a matrix and moves all of the non-empty cells somewhere else.
    my $matrix = shift;
    my $move_these = cells_to_move($matrix);
    for my $cell (@$move_these){
        my ($i, $j) = @$cell;
        # Move the cell, provided that the cell hasn't been moved
        # already and the subsequent edits don't lead to a dead end.
        $matrix->[$i][$j] = 0
            if $matrix->[$i][$j]
            and other_edits($matrix, $cell, 0, $j);
    }
}

sub cells_to_move {
    # Returns a list of non-empty cells.
    my $matrix = shift;
    my $i = -1;
    my @cells = ();
    for my $row (@$matrix){
        $i ++;
        for my $j (0 .. @$row - 1){
            push @cells, [$i, $j] if $matrix->[$i][$j];
        }
    }
    return \@cells;
}

sub other_edits {
    my ($matrix, $cell, $step, $last_j) = @_;

    # We have succeeded if we've already made 3 edits.
    $step ++;
    return 1 if $step > 3;

    # Determine the roster of next edits to fix the row or
    # column total upset by our prior edit.
    my ($i, $j) = @$cell;
    my @fixes;
    if ($step == 1){
        @fixes = 
            map  { [$i, $_] }
            grep { $_ != $j and not $matrix->[$i][$_] }
            0 .. @{$matrix->[0]} - 1
        ;
        shuffle(\@fixes);
    }
    elsif ($step == 2) {
        @fixes = 
            map  { [$_, $j] }
            grep { $_ != $i and $matrix->[$_][$j] }
            0 .. @$matrix - 1
        ;
        shuffle(\@fixes);
    }
    else {
        # On the last edit, the column of the fix must be
        # the same as the column of the initial edit.
        @fixes = ([$i, $last_j]) unless $matrix->[$i][$last_j];
    }

    for my $f (@fixes){
        # If all subsequent fixes succeed, we are golden: make
        # the current fix and return true.
        if ( other_edits($matrix, [@$f], $step, $last_j) ){
            $matrix->[$f->[0]][$f->[1]] = $step == 2 ? 0 : 1;
            return 1;
        }
    }

    # Failure if we get here.
    return;
}

sub shuffle {
    my $array = shift;
    my $i = scalar(@$array);
    my $j;
    for (@$array ){
        $i --;
        $j = int rand($i + 1);
        @$array[$i, $j] = @$array[$j, $i] unless $i == $j;
    }
}