问题 F＃中的组合单子

我将展示如何创建一个EitherWriter，有两种方法可以构建其中一种，具体取决于您如何订购 Either 和 Writer 但我将展示似乎最符合您所需工作流程的示例。

我也将简化编写器，使其只记录到一个 string list。更全面的编写器实现将使用 mempty 和 mappend 抽象适当的类型。

类型定义：

type EitherWriter<'a,'b>  = EWriter of string list * Choice<'a,'b>

基本功能：

let runEitherWriter = function
    |EWriter (st, v) -> st, v

let return' x = EWriter ([], Choice1Of2 x)

let bind x f =
    let (st, v) = runEitherWriter x
    match v with
    |Choice1Of2 a -> 
        match runEitherWriter (f a) with
        |st', Choice1Of2 a -> EWriter(st @ st', Choice1Of2 a)
        |st', Choice2Of2 b -> EWriter(st @ st', Choice2Of2 b)
    |Choice2Of2 b -> EWriter(st, Choice2Of2 b)

我喜欢在独立模块中定义它们，然后我可以直接使用它们或引用它们来创建计算表达式。同样，我将保持简单，只做最基本的可用实现：

type EitherWriterBuilder() =
    member this.Return x = return' x
    member this.ReturnFrom x = x
    member this.Bind(x,f) = bind x f
    member this.Zero() = return' ()

let eitherWriter = EitherWriterBuilder()

这有什么用的吗？

F＃的乐趣和利润有一些很好的信息 铁路导向编程 以及它与竞争方法相比带来的优势。

这些示例基于自定义 Result<'TSuccess,'TFailure> 但是，当然，它们同样可以使用F＃的内置功能 Choice<'a,'b> 类型。

虽然我们可能会遇到以这种面向铁路的形式表达的代码，但我们更不可能遇到预先编写的代码，可以直接使用 EitherWriter。因此，该方法的实用性取决于从简单的成功/失败代码到与上述monad兼容的容易的转换。

以下是成功/失败功能的示例：

let divide5By = function
    |0.0 -> Choice2Of2 "Divide by zero"
    |x -> Choice1Of2 (5.0/x)

此功能只用提供的数字除以5。如果该数字为非零，则返回包含结果的成功，如果提供的数字为零，则返回失败告诉我们我们已尝试除以零。

我们现在需要一个辅助函数来将这样的函数转换为可用于我们的函数 EitherWriter。可以做到这一点的功能是这样的：

let eitherConv logSuccessF logFailF f = 
    fun v ->
        match f v with
        |Choice1Of2 a -> EWriter(["Success: " + logSuccessF a], Choice1Of2 a)
        |Choice2Of2 b -> EWriter(["ERROR: " + logFailF b], Choice2Of2 b)

它需要一个描述如何记录成功的函数，一个描述如何记录失败的函数和一个绑定函数 Either monad和它返回一个绑定函数 EitherWriter 单子。

我们可以像这样使用它：

let ew = eitherWriter {
    let! x = eitherConv (sprintf "%f") (sprintf "%s") divide5By 6.0
    let! y = eitherConv (sprintf "%f") (sprintf "%s") divide5By 3.0
    let! z = eitherConv (sprintf "%f") (sprintf "%s") divide5By 0.0
    return (x, y, z)
}

let (log, _) = runEitherWriter ew

printfn "%A" log

然后返回：

[“成功：0.833333”; “成功：1.666667”; “错误：除以零”]